'Yazar		: Ramesh Srinivasan, Microsoft MVP [Windows Shell/User]
'Açıklama	: Tüm kullanıcı hesapları, onlara ait SID'ler ve Profil yolları.
'Telif		: Copyright © 2005-2006, Ramesh Srinivasan
'İşletim Sistemi: Windows® XP
'Web		: http://windowsxp.mvps.org & http://www.turkceyazilim.net

Set WshShell = CreateObject("Wscript.Shell")
Set fso = Wscript.CreateObject("Scripting.FilesystemObject")
fName = WshShell.SpecialFolders("Desktop") & "\SIDlistesi.txt"
Set b = fso.CreateTextFile(fName, true)
b.writeblanklines 1
b.writeline string(61,"*")
b.writeline "Tüm kullanıcı hesapları, onlara ait SID'ler ve Profil yolları."
b.WriteLine "SIDListesi.vbs - Copyright © 2005-2006, Ramesh Srinivasan"
b.WriteLine "WWW: http://windowsxp.mvps.org & http://www.turkceyazilim.net"
b.writeline string(61,"*")
b.writeblanklines 1

strProfilListesi = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\"
strBilgisayar = "."
Set objWMIService = GetObject("winmgmts:\\" & strBilgisayar & "\root\cimv2")
Set colAccounts = objWMIService.ExecQuery _
    ("Select * From Win32_UserAccount")

For Each objAccount in colAccounts
	If objAccount.Name = "HelpAssistant" or objAccount.Name = "SUPPORT_388945a0" then
	else
		b.writeline "K. Adı  	 : " & objAccount.Name
		b.writeline "SID      	 : " & objAccount.SID
		b.writeline "Profil Klasörü 	 : " & GetHomePath(objAccount.SID)
		b.writeblanklines 1
	end if
Next

Function GetHomePath(strSID)
	On Error Resume Next
		GetHomePath = WshShell.ExpandEnvironmentStrings(Trim(WshShell.RegRead (strProfilListesi & strSID & "\ProfileImagePath")))
	On Error Goto 0
End Function

b.writeline string(61,"*")
b.close
WshShell.Run "notepad.exe " & fName

Set fso = Nothing
set Wshshell = Nothing